First real version of item detail page

* Split the InventoryTable view/controller out from the existing inventory view/controller. This is a simpler component which only includes the table itself, and not the scrollbox, panel or header used on the crafting page. * Create the FullRecipe view/controller to represent the expanded version of a recipe shown on the item page (as compared to the terser version on the crafting page). * Rename the existing Recipe view/controller to MinimalRecipe to avoid confusing the two. * Refactor the CSS for the Stack view/controller so that it can be shared between the Inventory and InventoryTable views. * Incorporate all these new controllers into the item page and hook up the necessary model logic to drive them.
2015-02-09 21:15:09 -08:00
parent 996c8823a3
commit 46427a70f6
23 changed files with 528 additions and 54 deletions
@@ -0,0 +1,90 @@
+###
+Crafting Guide - full_recipe_controller.coffee
+
+Copyright (c) 2015 by Redwood Labs
+All rights reserved.
+###
+
+BaseController           = require './base_controller'
+CraftingGridController   = require './crafting_grid_controller'
+{Duration}               = require '../constants'
+ImageLoader              = require './image_loader'
+Inventory                = require '../models/inventory'
+InventoryTableController = require './inventory_table_controller'
+
+########################################################################################################################
+
+module.exports = class FullRecipeController extends BaseController
+
+    constructor: (options={})->
+        if not options.modPack? then throw new Error 'options.modPack is required'
+        options.imageLoader ?= new ImageLoader defaultUrl:'/images/unknown.png'
+        options.templateName = 'full_recipe'
+        super options
+
+        @_imageLoader = options.imageLoader
+        @modPack     = options.modPack
+
+    # BaseController Overrides #####################################################################
+
+    onDidRender: ->
+        @gridController = @addChild CraftingGridController, '.view__crafting_grid',
+            modPack:     @modPack
+            imageLoader: @_imageLoader
+
+        @inputController = @addChild InventoryTableController, '.input .view__inventory_table',
+            editable: false
+            model:    new Inventory
+            modPack:  @modPack
+
+        @outputController = @addChild InventoryTableController, '.output .view__inventory_table',
+            editable: false
+            model:    new Inventory
+            modPack:  @modPack
+
+        @$tool = @$('.tool p')
+        super
+
+    refresh: ->
+        @gridController.model = @model
+        @$tool.html @_findToolNames().join ', '
+
+        @$el.tooltip show:{delay:Duration.fast, duration:Duration.fast}
+
+        @_refreshInputs()
+        @_refreshOutputs()
+
+        super
+
+    # Backbone.View Methods ########################################################################
+
+    events: ->
+        return _.extend super,
+            'click a': 'routeLinkClick'
+
+    # Private Methods ##############################################################################
+
+    _findToolNames: ->
+        result = []
+        if @model?
+            for stack in @model.tools
+                name = @modPack.findName stack.slug
+                result.push name if name?
+        return result
+
+    _refreshInputs: ->
+        inputs = @inputController.model
+        inputs.clear()
+
+        if @model?
+            for stack in @model.input
+                inputs.add stack.slug, stack.quantity
+
+
+    _refreshOutputs: ->
+        outputs = @outputController.model
+        outputs.clear()
+
+        if @model?
+            for stack in @model.output
+                outputs.add stack.slug, stack.quantity