Several large refactorings
* Refactor location of all data files to include a subdirectory for the mod version * Update the BaseModel class to allow models to load themselves from any text file (whether JSON or CG) * Refactor ModPack & ModVersion to move the laoding functionality in one into the other (and use the new stuff in BaseModel) * Move the parser versions into a new subdirectory which allows for future additional parsers
This commit is contained in:
Andrew Miner
@@ -0,0 +1,220 @@
|
||||
###
|
||||
Crafting Guide - mod_version_parser_v1.coffee
|
||||
|
||||
Copyright (c) 2014-2015 by Redwood Labs
|
||||
All rights reserved.
|
||||
###
|
||||
|
||||
Item = require '../item'
|
||||
ModVersion = require '../mod_version'
|
||||
Recipe = require '../recipe'
|
||||
Stack = require '../stack'
|
||||
|
||||
########################################################################################################################
|
||||
|
||||
module.exports = class ModVersionParserV1
|
||||
|
||||
constructor: (options={})->
|
||||
if not options.modVersion? then throw new Error 'options.modVersion is required'
|
||||
@_modVersion = options.modVersion
|
||||
@_errorLocation = 'the header information'
|
||||
|
||||
parse: (data)->
|
||||
return @_parseModVersion data
|
||||
|
||||
unparse: ->
|
||||
return @_unparseModVersion()
|
||||
|
||||
# Private Methods ##############################################################################
|
||||
|
||||
_findOrCreateItem: (name)->
|
||||
item = @_modVersion.findItemByName name
|
||||
if not item?
|
||||
item = new Item modVersion:@_modVersion, name:name
|
||||
@_modVersion.registerSlug item.slug, item.name
|
||||
return item
|
||||
|
||||
_parseModVersion: (data)->
|
||||
if not data? then throw new Error 'mod description data is missing'
|
||||
if not data.name? then throw new Error 'name is required'
|
||||
if not data.version? then throw new Error 'version is required'
|
||||
if not _.isArray(data.recipes) then throw new Error 'recipes must be an array'
|
||||
|
||||
if data.name isnt @_modVersion.name
|
||||
throw new Error "the data is for #{data.name}, not #{@_modVersion.name} as expected"
|
||||
if data.version isnt @_modVersion.version
|
||||
throw new Error "the data is for version #{data.version}, not #{@_modVersion.version} as expected"
|
||||
|
||||
@_modVersion.description = data.description or ''
|
||||
@_parseRawMaterials data.raw_materials
|
||||
|
||||
for index in [0...data.recipes.length]
|
||||
@_errorLocation = "recipe #{index + 1}"
|
||||
recipeData = data.recipes[index]
|
||||
recipe = @_parseRecipe recipeData
|
||||
recipe._originalIndex = index
|
||||
|
||||
return @_modVersion
|
||||
|
||||
_parseRawMaterials: (data)->
|
||||
return unless data? and data.length > 0
|
||||
|
||||
results = []
|
||||
for name in data
|
||||
item = @_findOrCreateItem name
|
||||
item.isGatherable = true
|
||||
results.push item
|
||||
|
||||
_parseRecipe: (data)->
|
||||
if not data? then throw new Error "recipe data is missing for #{@_errorLocation}"
|
||||
if not data.output? then throw new Error "#{@_errorLocation} is missing output"
|
||||
|
||||
data.output = if _.isArray(data.output) then data.output else [data.output]
|
||||
names = (e for e in _.flatten(data.output) when _.isString(e))
|
||||
if names.length is 0 then throw new Error "#{@_errorLocation} has an empty output list"
|
||||
|
||||
item = @_findOrCreateItem names[0]
|
||||
@_errorLocation = "recipe for #{item.name}"
|
||||
|
||||
if not data.input? then throw new Error "#{@_errorLocation} is missing input"
|
||||
data.tools ?= []
|
||||
|
||||
attributes =
|
||||
item: item,
|
||||
output: @_parseStackList(data.output, field:'output', canBeEmpty:false)
|
||||
input: @_parseStackList(data.input, field:'input', canBeEmpty:true)
|
||||
tools: @_parseStackList(data.tools, field:'tools', canBeEmpty:true)
|
||||
attributes.pattern = data.pattern if data.pattern?
|
||||
|
||||
recipe = new Recipe attributes
|
||||
return recipe
|
||||
|
||||
_parseStack: (data, options={})->
|
||||
errorBase = "#{options.field} element #{options.index} for #{@_errorLocation}"
|
||||
if not data? then throw new Error "#{errorBase} is missing"
|
||||
|
||||
if _.isString(data) then data = [1, data]
|
||||
if not _.isArray(data) then throw new Error "#{errorBase} must be an array"
|
||||
|
||||
if data.length is 1 then data.unshift 1
|
||||
if data.length isnt 2 then throw new Error "#{errorBase} must have at least one element"
|
||||
if not _.isNumber(data[0]) then throw new Error "#{errorBase} must start with a number"
|
||||
|
||||
name = data[1]
|
||||
slug = _.slugify name
|
||||
@_modVersion.registerSlug slug, name
|
||||
|
||||
return new Stack itemSlug:slug, quantity:data[0]
|
||||
|
||||
_parseStackList: (data, options={})->
|
||||
if not data? then throw new Error "#{@_errorLocation} must have an #{options.field} field"
|
||||
|
||||
if not _.isArray(data) then data = [data]
|
||||
if data.length is 0 and not options.canBeEmpty
|
||||
throw new Error "#{options.field} for #{@_errorLocation} cannot be empty"
|
||||
|
||||
result = []
|
||||
for index in [0...data.length]
|
||||
stackData = data[index]
|
||||
result.push @_parseStack stackData, field:options.field, index:index
|
||||
|
||||
return result
|
||||
|
||||
# Un-parsing Methods ###########################################################################
|
||||
|
||||
_unparseModVersion: (modVersion)->
|
||||
result = []
|
||||
result.push '{\n'
|
||||
result.push ' "dataVersion": 1,\n'
|
||||
result.push ' "name": "' + modVersion.name + '",\n'
|
||||
result.push ' "version": "' + modVersion.version + '",\n'
|
||||
if modVersion.description.length > 0
|
||||
result.push ' "description": "' + modVersion.description + '",\n'
|
||||
|
||||
rawMaterials = (item.name for slug, item of modVersion.items when item.isGatherable)
|
||||
rawMaterials.sort()
|
||||
if rawMaterials.length > 0
|
||||
result.push ' "raw_materials": [\n'
|
||||
firstItem = true
|
||||
for material in rawMaterials
|
||||
if not firstItem then result.push ',\n'
|
||||
result.push ' "' + material + '"'
|
||||
firstItem = false
|
||||
result.push '\n ],\n'
|
||||
|
||||
result.push ' "recipes": [\n'
|
||||
|
||||
items = (item for slug, item of modVersion.items when item.isCraftable)
|
||||
items.sort (a, b)-> a.compareTo b
|
||||
|
||||
firstItem = true
|
||||
for item in items
|
||||
for recipe in item.recipes
|
||||
result.push if firstItem then ' {\n' else ' }, {\n'
|
||||
@_unparseRecipe recipe, result
|
||||
firstItem = false
|
||||
result.push ' }\n'
|
||||
|
||||
result.push ' ]\n'
|
||||
result.push '}'
|
||||
|
||||
return result.join ''
|
||||
|
||||
_unparseRecipe: (recipe, result=[])->
|
||||
result.push ' "output": '
|
||||
@_unparseStackList recipe.output, result, sort:false
|
||||
|
||||
if recipe.input.length > 0
|
||||
result.push ',\n'
|
||||
result.push ' "input": '
|
||||
@_unparseStackList recipe.input, result
|
||||
|
||||
if recipe.pattern?
|
||||
result.push ',\n'
|
||||
result.push ' "pattern": "'
|
||||
result.push recipe.pattern
|
||||
result.push '"'
|
||||
|
||||
if recipe.tools.length > 0
|
||||
result.push ',\n'
|
||||
result.push ' "tools": '
|
||||
@_unparseStackList recipe.tools, result
|
||||
|
||||
result.push '\n'
|
||||
return result
|
||||
|
||||
_unparseStackList: (stackList, result, options={})->
|
||||
options.sort ?= true
|
||||
|
||||
if stackList.length is 0
|
||||
result.push '[]'
|
||||
else if stackList.length is 1
|
||||
stack = stackList[0]
|
||||
if stack.quantity is 1
|
||||
result.push '"' + @_modVersion.findName(stack.itemSlug) + '"'
|
||||
else
|
||||
result.push '[[' + stack.quantity + ', "' + @_modVersion.findName(stack.itemSlug) + '"]]'
|
||||
else
|
||||
result.push '['
|
||||
|
||||
stacks = stackList.slice()
|
||||
if options.sort
|
||||
stacks.sort (a, b)->
|
||||
if a.quantity isnt b.quantity
|
||||
return if a.quantity > b.quantity then -1 else +1
|
||||
if a.itemSlug isnt b.itemSlug
|
||||
return if a.itemSlug < b.itemSlug then -1 else +1
|
||||
return 0
|
||||
|
||||
firstItem = true
|
||||
for stack in stacks
|
||||
result.push ', ' if not firstItem
|
||||
if stack.quantity is 1
|
||||
result.push '"' + @_modVersion.findName(stack.itemSlug) + '"'
|
||||
else
|
||||
result.push '[' + stack.quantity + ', "' + @_modVersion.findName(stack.itemSlug) + '"]'
|
||||
firstItem = false
|
||||
|
||||
result.push ']'
|
||||
|
||||
return result
|
||||
@@ -0,0 +1,341 @@
|
||||
###
|
||||
Crafting Guide - mod_version_parser_v2.coffee
|
||||
|
||||
Copyright (c) 2014-2015 by Redwood Labs
|
||||
All rights reserved.
|
||||
###
|
||||
|
||||
Item = require '../item'
|
||||
ModVersion = require '../mod_version'
|
||||
Recipe = require '../recipe'
|
||||
Stack = require '../stack'
|
||||
StringBuilder = require '../string_builder'
|
||||
|
||||
########################################################################################################################
|
||||
|
||||
module.exports = class ModVersionParserV2
|
||||
|
||||
constructor: (options={})->
|
||||
if not options.modVersion? then throw new Error 'options.modVersion is required'
|
||||
options.showAllErrors ?= false
|
||||
|
||||
@_modVersion = options.modVersion
|
||||
@_showAllErrors = options.showAllErrors
|
||||
|
||||
# Class Methods ################################################################################
|
||||
|
||||
@COMMAND = /\ *([^:]*):?(.*)/
|
||||
|
||||
@COMMENT = /([^\\]?)#.*/
|
||||
|
||||
@INTEGER = /[0-9]+/
|
||||
|
||||
@PATTERN = /^[0-9.]{3} ?[0-9.]{3} ?[0-9.]{3}$/
|
||||
|
||||
@STACK = /^([0-9]+) +(.*)$/
|
||||
|
||||
# Public Methods ###############################################################################
|
||||
|
||||
parse: (text)->
|
||||
@_modVersionData = {}
|
||||
@_lineNumber = 1
|
||||
|
||||
lines = text.split '\n'
|
||||
for i in [0...lines.length]
|
||||
@_lineNumber = i + 1
|
||||
commands = @_parseLine lines[i]
|
||||
for command in commands
|
||||
@_handleErrors @_execute, command
|
||||
|
||||
return @_handleErrors @_buildModVersion, @_modVersionData, @_modVersion
|
||||
|
||||
unparse: ->
|
||||
builder = new StringBuilder context:@_modVersion
|
||||
@_unparseModVersion builder
|
||||
return builder.toString()
|
||||
|
||||
# Private Methods ##############################################################################
|
||||
|
||||
_execute: (command)->
|
||||
method = this["_command_#{command.name}"]
|
||||
if not method? then throw new Error "Unknown command: #{command.name}"
|
||||
|
||||
@_handleErrors method, command.args
|
||||
|
||||
_parseLine: (line)->
|
||||
line = line.replace ModVersionParserV2.COMMENT, '$1'
|
||||
line = line.trim()
|
||||
return [] if line.length is 0
|
||||
|
||||
lineParts = (part.trim() for part in line.split(';'))
|
||||
commands = []
|
||||
for linePart in lineParts
|
||||
continue if linePart.length is 0
|
||||
|
||||
match = ModVersionParserV2.COMMAND.exec linePart
|
||||
if not match? then throw new Error "Expected <command>: <args>, but found: \"#{linePart}\""
|
||||
|
||||
args = []
|
||||
args = (s.trim() for s in match[2].split(',')) if match[2]?
|
||||
commands.push name:match[1], args:args
|
||||
|
||||
return commands
|
||||
|
||||
_handleErrors: (callback, args...)->
|
||||
if args.length is 1 and _.isArray(args[0]) then args = args[0]
|
||||
|
||||
try
|
||||
callback.apply this, args
|
||||
catch e
|
||||
e.message = "line #{@_lineNumber}: #{e.message}"
|
||||
if not @_showAllErrors then throw e
|
||||
logger.error e.message
|
||||
|
||||
# Command Methods ##############################################################################
|
||||
|
||||
_command_description: (descriptionParts...)->
|
||||
if @_modVersionData.description? then throw new Error 'duplicate declaration of "description"'
|
||||
@_modVersionData.description = descriptionParts.join ', '
|
||||
|
||||
_command_extras: (extraTerms...)->
|
||||
if not @_recipeData? then throw new Error 'cannot declare "extras" before "recipe"'
|
||||
if @_recipeData.extras? then throw new Error 'duplicate declaration of "extras"'
|
||||
|
||||
@_recipeData.extras = []
|
||||
for term in extraTerms
|
||||
match = ModVersionParserV2.STACK.exec term
|
||||
if match?
|
||||
@_recipeData.extras.push quantity:parseInt(match[1]), name:match[2]
|
||||
else
|
||||
@_recipeData.extras.push quantity:1, name:term
|
||||
|
||||
_command_gatherable: (gatherable)->
|
||||
if not @_itemData? then throw new Error 'cannot declare "gatherable" before "item"'
|
||||
if @_itemData.gatherable? then throw new Error 'duplicate declaration of "gatherable"'
|
||||
if not (gatherable in ['yes', 'no']) then throw new Error 'gatherable must be either "yes" or "no"'
|
||||
|
||||
@_itemData.gatherable = (gatherable is 'yes')
|
||||
|
||||
_command_item: (name='')->
|
||||
if not name.length > 0 then throw new Error 'the item name cannot be empty'
|
||||
|
||||
@_itemData = name:name, line:@_lineNumber
|
||||
@_modVersionData.items ?= []
|
||||
@_modVersionData.items.push @_itemData
|
||||
|
||||
@_recipeData = null
|
||||
|
||||
_command_name: (name='')->
|
||||
if @_modVersionData.name? then throw new Error 'duplicate declaration of "name"'
|
||||
if not name.length > 0 then throw new Error 'the mod name cannot be empty'
|
||||
|
||||
@_modVersionData.name = name
|
||||
|
||||
_command_input: (inputNames...)->
|
||||
if not @_recipeData? then throw new Error 'cannot declare "input" before "recipe"'
|
||||
if @_recipeData.input? then throw new Error 'duplicate declaration of "input"'
|
||||
|
||||
@_recipeData.input = []
|
||||
for name in inputNames
|
||||
if name.length is 0 then throw new Error 'input names cannot be empty'
|
||||
@_recipeData.input.push name
|
||||
|
||||
_command_pattern: (pattern='')->
|
||||
if not @_recipeData? then throw new Error 'cannot declare "pattern" before "recipe"'
|
||||
if @_recipeData.pattern? then throw new Error 'duplicate declaration of "pattern"'
|
||||
if not ModVersionParserV2.PATTERN.test pattern
|
||||
throw new Error 'a pattern must have 9 digits using 0-9 for items and "." for an empty spot;
|
||||
spaces are optional'
|
||||
|
||||
@_recipeData.pattern = pattern
|
||||
|
||||
_command_quantity: (quantity)->
|
||||
if not @_recipeData? then throw new Error 'cannot declare "quantity" before "recipe"'
|
||||
if @_recipeData.quantity? then throw new Error 'duplicate declaration of "quantity"'
|
||||
if not ModVersionParserV2.INTEGER.test(quantity) then throw new Error 'quantity must be an integer'
|
||||
|
||||
@_recipeData.quantity = parseInt quantity
|
||||
|
||||
_command_recipe: ->
|
||||
if not @_itemData? then throw new Error 'cannot delcare "recipe" before "item"'
|
||||
|
||||
@_recipeData = line:@_lineNumber
|
||||
@_itemData.recipes ?= []
|
||||
@_itemData.recipes.push @_recipeData
|
||||
|
||||
_command_schema: -> # do nothing
|
||||
|
||||
_command_tools: (toolNames...)->
|
||||
if not @_recipeData? then throw new Error 'cannot declare "tools" before "recipe"'
|
||||
if @_recipeData.tools? then throw new Error 'duplicate declaration of "tools"'
|
||||
|
||||
@_recipeData.tools = []
|
||||
for name in toolNames
|
||||
if name.length is 0 then throw new Error 'tool names cannot be empty'
|
||||
@_recipeData.tools.push name
|
||||
|
||||
_command_version: (version='')->
|
||||
if @_modVersionData.version? then throw new Error 'duplicate declaration of "version"'
|
||||
if version.length is 0 then throw new Error 'version cannot be empty'
|
||||
|
||||
@_modVersionData.version = version
|
||||
|
||||
# Object Creation Methods ######################################################################
|
||||
|
||||
_buildModVersion: (modVersionData, modVersion)->
|
||||
if not modVersionData.name? then throw new Error 'the "name" declaration is required'
|
||||
if not modVersionData.version? then throw new Error 'the "version" declaration is required'
|
||||
|
||||
if modVersionData.name isnt modVersion.name
|
||||
throw new Error "modVersionData name (#{modVersionData.name})
|
||||
must match the ModVersion (#{modVersion.name})"
|
||||
if modVersionData.version isnt modVersion.version
|
||||
throw new Error "modVersionData version (#{modVersionData.version})
|
||||
must match the ModVersion (#{modVersion.version})"
|
||||
|
||||
modVersionData.description ?= ''
|
||||
modVersionData.items ?= []
|
||||
|
||||
modVersion.description = modVersionData.description
|
||||
|
||||
for itemData in modVersionData.items
|
||||
@_handleErrors @_buildItem, modVersion, itemData
|
||||
|
||||
return modVersion
|
||||
|
||||
_buildItem: (modVersion, itemData)->
|
||||
@_lineNumber = itemData.line
|
||||
itemData.gatherable ?= false
|
||||
itemData.recipes ?= []
|
||||
|
||||
item = new Item modVersion:modVersion, name:itemData.name, isGatherable:itemData.gatherable
|
||||
|
||||
for recipeData in itemData.recipes
|
||||
@_handleErrors @_buildRecipe, modVersion, item, recipeData
|
||||
|
||||
return item
|
||||
|
||||
_buildRecipe: (modVersion, item, recipeData)->
|
||||
@_lineNumber = recipeData.line
|
||||
if not recipeData.input? then throw new Error 'the "input" declaration is required'
|
||||
if not recipeData.pattern? then throw new Error 'the "pattern" declaration is required'
|
||||
|
||||
recipeData.quantity ?= 1
|
||||
recipeData.extras ?= []
|
||||
recipeData.tools ?= []
|
||||
|
||||
inputStacks = []
|
||||
for name in recipeData.input
|
||||
slug = _.slugify name
|
||||
modVersion.registerSlug slug, name
|
||||
inputStacks.push new Stack itemSlug:slug, quantity:0
|
||||
|
||||
for c in recipeData.pattern
|
||||
continue if c is '.'
|
||||
continue if c is ' '
|
||||
stack = inputStacks[parseInt(c)]
|
||||
if not stack? then throw new Error "there is no input #{c} in this recipe"
|
||||
stack.quantity += 1
|
||||
|
||||
for i in [0...inputStacks.length]
|
||||
stack = inputStacks[i]
|
||||
if stack.quantity is 0
|
||||
name = modVersion.findName stack.itemSlug
|
||||
throw new Error "#{name} is an input for this recipe, but it is not in the pattern"
|
||||
|
||||
outputStacks = [ new Stack itemSlug:item.slug, quantity:recipeData.quantity ]
|
||||
for extraData in recipeData.extras
|
||||
slug = _.slugify extraData.name
|
||||
modVersion.registerSlug slug, extraData.name
|
||||
outputStacks.push new Stack itemSlug:slug, quantity:extraData.quantity
|
||||
|
||||
toolStacks = []
|
||||
for name in recipeData.tools
|
||||
slug = _.slugify name
|
||||
modVersion.registerSlug slug, name
|
||||
toolStacks.push new Stack itemSlug:slug, quantity:1
|
||||
|
||||
attributes =
|
||||
input: inputStacks
|
||||
item: item
|
||||
pattern: recipeData.pattern
|
||||
output: outputStacks
|
||||
tools: toolStacks
|
||||
|
||||
recipe = new Recipe attributes
|
||||
return recipe
|
||||
|
||||
# Un-parsing Methods ###########################################################################
|
||||
|
||||
_unparseModVersion: (builder)->
|
||||
itemList = _.values @modVersion.items
|
||||
itemList.sort (a, b)-> a.compareTo b
|
||||
|
||||
builder
|
||||
.line 'schema: ', 2
|
||||
.line 'name: ', @modVersion.name
|
||||
.line 'version: ', @modVersion.version
|
||||
.onlyIf @modVersion.description?, => builder.line 'description: ', @modVersion.description
|
||||
.line()
|
||||
.onlyIf itemList.length > 0, =>
|
||||
builder.loop itemList, delimiter:'\n', onEach:(b, i)=> @_unparseItem(b, i)
|
||||
.outdent()
|
||||
|
||||
_unparseItem: (builder, item)->
|
||||
builder
|
||||
.line 'item: ', item.name
|
||||
.indent()
|
||||
.onlyIf item.isGatherable, => builder.line 'gatherable: yes'
|
||||
.onlyIf item.recipes.length > 0, =>
|
||||
builder.loop item.recipes, delimiter:'', onEach:(b, r)=> @_unparseRecipe(b, r)
|
||||
.outdent()
|
||||
|
||||
_unparseRecipe: (builder, recipe)->
|
||||
inputNames = (builder.context.findName(stack.itemSlug) for stack in recipe.input)
|
||||
inputNames.sort()
|
||||
|
||||
patternMap = {'.', '.'}
|
||||
for i in [0...recipe.input.length]
|
||||
stack = recipe.input[i]
|
||||
patternMap["#{i}"] = "#{inputNames.indexOf builder.context.findName(stack.itemSlug)}"
|
||||
|
||||
pattern = recipe.pattern or recipe.defaultPattern
|
||||
newPattern = []
|
||||
for c in pattern.split('')
|
||||
newPattern.push patternMap[c]
|
||||
newPattern = newPattern.join ''
|
||||
newPattern = newPattern.replace /(...)(...)(...)/, '$1 $2 $3'
|
||||
|
||||
quantity = recipe.output[0].quantity
|
||||
|
||||
extraOutputs = recipe.output[0...recipe.output.length]
|
||||
extraOutputs.shift()
|
||||
|
||||
builder
|
||||
.line 'recipe:'
|
||||
.indent()
|
||||
.onlyIf extraOutputs.length > 0, =>
|
||||
builder
|
||||
.push 'extras: '
|
||||
.call => @_unparseStackList builder, extraOutputs
|
||||
.line()
|
||||
.push 'input: '
|
||||
.loop inputNames
|
||||
.line()
|
||||
.line 'pattern: ', newPattern
|
||||
.onlyIf quantity > 1, => builder.line 'quantity: ', quantity
|
||||
.onlyIf recipe.tools.length > 0, =>
|
||||
builder
|
||||
.push 'tools: '
|
||||
.call => @_unparseStackList builder, recipe.tools
|
||||
.line()
|
||||
.outdent()
|
||||
|
||||
_unparseStackList: (builder, stackList)->
|
||||
if stackList.length is 1 and stackList[0].quantity is 1
|
||||
builder.push builder.context.findName(stackList[0].itemSlug)
|
||||
else
|
||||
builder.loop stackList, onEach:(b, stack)=>
|
||||
builder
|
||||
.onlyIf stack.quantity > 1, => builder.push stack.quantity, ' '
|
||||
.push builder.context.findName stack.itemSlug
|
||||
Reference in New Issue
Block a user