Andrew Miner
380a78ef61
* Change default item URL to fall under /mod/<mod slug>/<item slug> but kept the old URL pattern around with the old behavior (i.e., find the first item with that slug) * Update Item to have a `qualifiedSlug` property which combines the item's own slug with its Mod's slug. Updated a lot of code all over to use this in preference to the plain slug. * Add a `localizeTo` method to Inventory to allow non-qualified slugs to be converted into qualified slugs within the inventory's stacks * Update ModPack to work with either qualified or unqualified slugs for relevant methods * Fix model state changes to happen before related events are triggered * Add a debounce to the CraftingPlan object when triggering a recraft due to changes in related objects (esp. its inventories) * Update the Inventory's sort to keep items sorted by mod before name with the Minecraft items sorted to the top * Fix `ModPack.findItemByName` to actually recursively use the Mod's method instead of slugifying the given name and looking for the slug (since this won't necessarily work anymore). * Ensure each Mod is assigned a reference to its containing ModPack * Fix NameFinder to only consider an item non-gatherable if it is also craftable * Update ModVersionParserV1 to assign qualified slugs to recipes for any items which are in the same mod (leaving any other slugs unqualified) * Add Underscore mixins for composing and decomposing slugs * Update old tests for the use of qualified slugs, and some new tests for the new methods added
109 lines
3.5 KiB
CoffeeScript
109 lines
3.5 KiB
CoffeeScript
###
|
|
Crafting Guide - recipe.coffee
|
|
|
|
Copyright (c) 2014-2015 by Redwood Labs
|
|
All rights reserved.
|
|
###
|
|
|
|
BaseModel = require './base_model'
|
|
Stack = require './stack'
|
|
|
|
########################################################################################################################
|
|
|
|
module.exports = class Recipe extends BaseModel
|
|
|
|
constructor: (attributes={}, options={})->
|
|
if attributes.item?
|
|
attributes.name = attributes.item.name
|
|
attributes.output ?= [new Stack slug:attributes.item.qualifiedSlug, quantity:1]
|
|
|
|
if not attributes.name? then throw new Error 'attributes.name is required'
|
|
if not attributes.input? then throw new Error 'attributes.input is required'
|
|
if not attributes.pattern? then throw new Error 'attributes.pattern is required'
|
|
|
|
attributes.item ?= null
|
|
attributes.output ?= [new Stack slug:_.slugify(attributes.name), quantity:1]
|
|
attributes.pattern = @_parsePattern attributes.pattern
|
|
attributes.tools ?= []
|
|
options.logEvents ?= false
|
|
super attributes, options
|
|
|
|
Object.defineProperties this,
|
|
slug: {get:@getSlug}
|
|
|
|
# Public Methods ###############################################################################
|
|
|
|
getItemSlugAt: (patternSlot)->
|
|
trueIndex = 0:0, 1:1, 2:2, 3:4, 4:5, 5:6, 6:8, 7:9, 8:10
|
|
patternDigit = @pattern[trueIndex[patternSlot]]
|
|
return null unless patternDigit?
|
|
return null unless patternDigit.match /[0-9]/
|
|
|
|
stack = @input[parseInt(patternDigit)]
|
|
return null unless stack?
|
|
|
|
return stack.slug
|
|
|
|
doesProduce: (itemSlug)->
|
|
for stack in @output
|
|
return true if stack.slug is itemSlug
|
|
return false
|
|
|
|
# Property Methods #############################################################################
|
|
|
|
getSlug: ->
|
|
return @item.qualifiedSlug if @item?
|
|
return @output[0].slug
|
|
|
|
# Object Overrides #############################################################################
|
|
|
|
toString: ->
|
|
result = [@constructor.name, " (", @cid, ") { name:", @name]
|
|
|
|
result.push ", input:["
|
|
needsDelimiter = false
|
|
for stack in @input
|
|
if needsDelimiter then result.push ', '
|
|
result.push stack.toString()
|
|
needsDelimiter = true
|
|
result.push ']'
|
|
|
|
result.push ", output:["
|
|
needsDelimiter = false
|
|
for stack in @output
|
|
if needsDelimiter then result.push ', '
|
|
result.push stack.toString()
|
|
needsDelimiter = true
|
|
result.push ']'
|
|
|
|
if @tools.length > 0
|
|
result.push ", tools:["
|
|
needsDelimiter = false
|
|
for stack in @tools
|
|
if needsDelimiter then result.push ', '
|
|
result.push stack.toString()
|
|
needsDelimiter = true
|
|
result.push ']'
|
|
|
|
result.push '}'
|
|
return result.join ''
|
|
|
|
# Private Methods ##############################################################################
|
|
|
|
_parsePattern: (pattern)->
|
|
return unless pattern?
|
|
|
|
pattern = pattern.replace /\ /g, ''
|
|
return if pattern.length is 0
|
|
|
|
pattern = pattern.replace /[^0-9]/g, '.'
|
|
|
|
array = pattern.split ''
|
|
array = array[0...9]
|
|
while array.length isnt 9
|
|
array.push '.'
|
|
|
|
pattern = array.join ''
|
|
pattern = pattern.replace /(...)(...)(...)/, '$1 $2 $3'
|
|
return pattern
|