Andrew Miner
380a78ef61
* Change default item URL to fall under /mod/<mod slug>/<item slug> but kept the old URL pattern around with the old behavior (i.e., find the first item with that slug) * Update Item to have a `qualifiedSlug` property which combines the item's own slug with its Mod's slug. Updated a lot of code all over to use this in preference to the plain slug. * Add a `localizeTo` method to Inventory to allow non-qualified slugs to be converted into qualified slugs within the inventory's stacks * Update ModPack to work with either qualified or unqualified slugs for relevant methods * Fix model state changes to happen before related events are triggered * Add a debounce to the CraftingPlan object when triggering a recraft due to changes in related objects (esp. its inventories) * Update the Inventory's sort to keep items sorted by mod before name with the Minecraft items sorted to the top * Fix `ModPack.findItemByName` to actually recursively use the Mod's method instead of slugifying the given name and looking for the slug (since this won't necessarily work anymore). * Ensure each Mod is assigned a reference to its containing ModPack * Fix NameFinder to only consider an item non-gatherable if it is also craftable * Update ModVersionParserV1 to assign qualified slugs to recipes for any items which are in the same mod (leaving any other slugs unqualified) * Add Underscore mixins for composing and decomposing slugs * Update old tests for the use of qualified slugs, and some new tests for the new methods added
103 lines
4.5 KiB
CoffeeScript
103 lines
4.5 KiB
CoffeeScript
###
|
|
Crafting Guide - mod_pack.test.coffee
|
|
|
|
Copyright (c) 2014-2015 by Redwood Labs
|
|
All rights reserved.
|
|
###
|
|
|
|
Item = require '../src/scripts/models/item'
|
|
Mod = require '../src/scripts/models/mod'
|
|
ModPack = require '../src/scripts/models/mod_pack'
|
|
ModVersion = require '../src/scripts/models/mod_version'
|
|
|
|
########################################################################################################################
|
|
|
|
buildcraft = industrialCraft = minecraft = modPack = null
|
|
|
|
########################################################################################################################
|
|
|
|
describe 'mod_pack.coffee', ->
|
|
|
|
beforeEach ->
|
|
minecraft = new Mod slug:'minecraft', name:'Minecraft'
|
|
minecraft.addModVersion new ModVersion modSlug:minecraft.slug, version:'1.7.10'
|
|
minecraft.activeModVersion.addItem new Item name:'Wool'
|
|
minecraft.activeModVersion.addItem new Item name:'Bed', recipes:['']
|
|
minecraft.activeModVersion.registerSlug 'iron_chestplate', 'Iron Chestplate'
|
|
|
|
buildcraft = new Mod slug:'buildcraft', name:'Buildcraft'
|
|
buildcraft.addModVersion new ModVersion modSlug:buildcraft.slug, version:'6.2.6'
|
|
buildcraft.activeModVersion.addItem new Item name:'Stone Gear', recipes:['']
|
|
buildcraft.activeModVersion.addItem new Item name:'Wrench', recipes:['']
|
|
buildcraft.activeVersion = Mod.Version.None
|
|
|
|
industrialCraft = new Mod slug:'industrial_craft', name:'Industrial Craft'
|
|
industrialCraft.addModVersion new ModVersion modSlug:industrialCraft.slug, version:'2.0'
|
|
industrialCraft.activeModVersion.addItem new Item name:'Resin'
|
|
industrialCraft.activeModVersion.addItem new Item name:'Rubber'
|
|
industrialCraft.activeModVersion.addItem new Item name:'Wrench', recipes:['']
|
|
industrialCraft.activeVersion = Mod.Version.None
|
|
|
|
modPack = new ModPack
|
|
modPack.addMod minecraft
|
|
modPack.addMod buildcraft
|
|
modPack.addMod industrialCraft
|
|
|
|
describe 'findItem', ->
|
|
|
|
it 'can find an item by partial slug', ->
|
|
item = modPack.findItem 'wool'
|
|
item.qualifiedSlug.should.equal 'minecraft__wool'
|
|
|
|
it 'can find an item by full slug', ->
|
|
item = modPack.findItem 'minecraft__wool'
|
|
item.name.should.equal 'Wool'
|
|
|
|
it 'can find an ambiguous item by full slug', ->
|
|
buildcraft.activeVersion = Mod.Version.Latest
|
|
industrialCraft.activeVersion = Mod.Version.Latest
|
|
item = modPack.findItem 'industrial_craft__wrench'
|
|
item.name.should.equal 'Wrench'
|
|
item.modVersion.mod.name.should.equal 'Industrial Craft'
|
|
|
|
it 'can find an ambiguous item by partial slug', ->
|
|
buildcraft.activeVersion = Mod.Version.Latest
|
|
industrialCraft.activeVersion = Mod.Version.Latest
|
|
item = modPack.findItem 'wrench'
|
|
item.name.should.equal 'Wrench'
|
|
item.modVersion.mod.name.should.equal 'Buildcraft'
|
|
|
|
describe 'findItemByName', ->
|
|
|
|
it 'finds the requested item', ->
|
|
item = modPack.findItemByName 'Bed'
|
|
item.name.should.equal 'Bed'
|
|
|
|
it 'ignores disabled mod versions', ->
|
|
item = modPack.findItemByName 'Stone Gear'
|
|
expect(item).to.be.null
|
|
|
|
describe 'findItemDisplay', ->
|
|
|
|
it 'returns all data for a regular Minecraft item', ->
|
|
display = modPack.findItemDisplay 'bed'
|
|
display.iconUrl.should.equal '/data/minecraft/1.7.10/images/bed.png'
|
|
display.itemUrl.should.equal '/mod/minecraft/bed'
|
|
display.itemName.should.equal 'Bed'
|
|
display.modSlug.should.equal 'minecraft'
|
|
|
|
it 'returns all data for an item in an enabled mod', ->
|
|
buildcraft.activeVersion = '6.2.6'
|
|
display = modPack.findItemDisplay 'stone_gear'
|
|
display.iconUrl.should.equal '/data/buildcraft/6.2.6/images/stone_gear.png'
|
|
display.itemUrl.should.equal '/mod/buildcraft/stone_gear'
|
|
display.itemName.should.equal 'Stone Gear'
|
|
display.modSlug.should.equal 'buildcraft'
|
|
|
|
it 'assumes an unfound item is from Minecraft', ->
|
|
display = modPack.findItemDisplay 'iron_chestplate'
|
|
display.iconUrl.should.equal '/data/minecraft/1.7.10/images/iron_chestplate.png'
|
|
display.itemUrl.should.equal '/mod/minecraft/iron_chestplate'
|
|
display.itemName.should.equal 'Iron Chestplate'
|
|
display.modSlug.should.equal 'minecraft'
|